avidemux_cli.exe does work in Windows 7

[therube]

Just noting...

I hadn't thought about it before, but in current /nightly/, while the avidemux.exe GUI no longer runs under Windows 7,
the command-line version, avidemux_cli.exe does still work in Windows 7 (at least the simple features I've tested, re-mux),
so a Windows 7 user might be able to pick up on recent updates that they may not have been able to use before.


Example:

Code Select Expand

:: CCOPY, but using Avidemux instead of ffmpeg - all extension types, version
:: SjB 01-28-2026 03-02-2026 03-15-2026

:: Avidemux has a command-line version, avidemux_cli.exe
:: by default, it stores, sets its settings in %appdata%
:: if you rename avidemux_cli.exe to avidemux_cli_portable.exe
:: it will store its settings in the "avidemux" directory, within /settings/

:: note:  this only works with video/video+audio files - NOT with audio only



@ECHO OFF

SET  avidemux_cli_portable="C:\WLIB\LeechFTP\VID\avidemux_2.8.2 r241212\avidemux_cli_portable.exe"
SET  OUTDIR=C:\OUT
:: SET  FORMAT=mp4
::  instead of forcing to a set EXT, default to using source EXT - so works with  mp4 flv avi...
::  note:  Avidemux only supports certain codecs in particular containers - so no AVC in .flv...
SET  FORMAT=%~x1
::  truncate the first char, i.e., ".MP4" becomes "MP4" - tis needed for --output-format (below)
SET  FORMAT=%FORMAT:~1%


ECHO Avidemux location:  %avidemux_cli_portable%
ECHO.

ECHO About to: avidemux_cli_portable.exe
ECHO   --load: %1
ECHO   --save: %OUTDIR%\out.%~n1.%FORMAT%
::             c:\out\<filename>.mp4
ECHO   ------: NOTE:   OUTPUT FILE IS   .OVERWRITTEN.   (by default, or otherwise)
ECHO.
PAUSE
ECHO.


:: output filename needs to be quoted if it contains <sp> !!!
%avidemux_cli_portable% --load %1 --video-codec Copy --audio-codec Copy --output-format %FORMAT% --save %OUTDIR%\out."%~n1".%FORMAT%  1>c:\out\avidemux_cli.log

grep -i "^[0-9]*:"                  c:\out\avidemux_cli.log
:: if "Cannot set", that is a FAIL condition, like trying to write .wmv1 to a WMV
grep -i "Cannot set that container" c:\out\avidemux_cli.log && ECHO Attempted ccopy FAILED !! FAIL !
:: if NOT found [saveCB], that means something went wrong & no output file was written
grep -i "\[saveCB\]"                c:\out\avidemux_cli.log
if %errorlevel% EQU 0  (ECHO Success!)  else  (ECHO Something went wrong. No output saved - FAIL!)
ECHO.
PAUSE

GOTO END:



:: avidemux_cli_portable.exe --load xxx.mp4 --save out.xxx.mp4
:: saves to .mkv (seemingly by default ?) otherwise this would work just as well
pause


:: avidemux_cli_portable.exe --load xxx.mp4 --video-codec copy --audio-codec copy --output-format mp4 --save out.xxx.mp4
:: accomplishes the same, but allows more leeway
pause


:: oh, this will do it, more succinctly <sp>
:: avidemux_cli_portable.exe --load xxx.mp4 --outputformat mp4 --save out.xxx.mp4


:: outputs can be redirected
:: 1> summary.log, is the short status; Saving ... AAC ... : MP4 ... Optimizing... - leaving un-redirected
:: 2>avidemux.log, is "detailed" log of what it did - most is just summary of loading libraries, followed by some notes of actual encoding (or otherwise)


:END


Code Select Expand

Microsoft Windows [Version 6.1.7601]

C:\out\SALAMANDER\avidemux64>CCOPY.A C:\out\2007-Iphone.mp4
Avidemux location:  "C:\out\SALAMANDER\avidemux64\avidemux_cli_portable.exe"

About to: avidemux_cli_portable.exe
  --load: C:\out\2007-Iphone.mp4
  --save: C:\OUT\out.2007-Iphone.mp4
  ------: NOTE:   OUTPUT FILE IS   .OVERWRITTEN.   (by default, or otherwise)

Press any key to continue . . .

Encoding Phase        : Saving
Encoding Audio codec  : AAC
Encoding Container        : MP4
Encoding Phase        : Optimizing...
0: C:\out\SALAMANDER\avidemux64\avidemux_cli_portable.exe
1: --load
2: C:\out\2007-Iphone.mp4
3: --video-codec
4: Copy
5: --audio-codec
6: Copy
7: --output-format
8: mp4
9: --save
10: C:\OUT\out.2007-Iphone.mp4
   17:35:49-674 [saveCB] Updating last write folder with C:\OUT\out.2007-Iphone.
mp4
Success!

Press any key to continue . . .

C:\out\SALAMANDER\avidemux64>